Single Post - Обмен кнопками

Single Post

Topic: Обмен кнопками

Author

Message

Orion9

Posted: Thu May 21, 2026 11:20 Post subject:

Кнопка для переключения количество строк на главной панели инструментов (разворачивание или сворачивание панели). Скрипт меняет значение BarLimitLines в Wincmd.ini.

Первое нажатие на кнопку разворачивает панель (BarLimitLines=0). Через 10 секунд панель свернется (BarLimitLines=1). Чтобы панель оставалась в развернутом виде, необходимо повторно нажать на кнопку в течении 10 секунд. Развернутая панель возвращается в исходное состояние нажатием на кнопку в третий раз.

Hidden text

Code:

Global gBarLinesTimer = false

RegisterCommand 60040 "ToggleBarLines"

SetHotkeyAction /K:C /H:F12 "ToggleBarLines"

Func ToggleBarLines()
# окно имеет прозрачность
Local bWinTrans = WinHasStyle(0x80000, 1, AUTORUN_TCHANDLE)
Local nLines
# чтение ключа
IniRead /R nLines %COMMANDER_INI% "Buttonbar" "BarLimitLines" 1
# панель развернута с запущенным таймером
If nLines = 0 And gBarLinesTimer Then
gBarLinesTimer = false
Sleep(50)
Return
EndIf
# переключение ключа
If nLines = 1 Then
IniWrite /R %COMMANDER_INI% "Buttonbar" "BarLimitLines" 0
Else
IniWrite /R %COMMANDER_INI% "Buttonbar" "BarLimitLines" 1
Endif
# запрет перерисовки окна
If Not bWinTrans Then SendMessage(AUTORUN_TCHANDLE, 11, 0, 0)
# двойная поылка cm_VisButtonBar
SendCommand(2901, 0, 1)
SendCommand(2901, 0, 1)
Sleep(10)
# снятие запрета перерисовки
If Not bWinTrans Then SendMessage(AUTORUN_TCHANDLE, 11, 1, 0)
WinRedraw(2)
# повторное чтение ключа
IniRead /R nLines %COMMANDER_INI% "Buttonbar" "BarLimitLines" 1
# панель свернута
If nLines = 1 Then
gBarLinesTimer = false
Sleep(50)
Return
EndIf
# запуск таймера
RunThread BarLinesTimer
EndFunc

Func BarLinesTimer()
Local nSeconds = 10
gBarLinesTimer = true
For i = 1 To nSeconds
For j = 1 To 20
Sleep(50)
If Not gBarLinesTimer Then Break
Next
If Not gBarLinesTimer Then Break
Next
gBarLinesTimer = false
# таймер был прерван
If i < nSeconds Then Return
# таймер сработал до конца
Local nLines
IniRead /R nLines %COMMANDER_INI% "Buttonbar" "BarLimitLines" 1
If nLines = 0 Then RunThread ToggleBarLines
EndFunc

Реализовано на плагине Autorun. Требуется последняя версия плагина.

Количество секунд можно поменять (nSeconds = 10). Вызов можно переназначить на другую комбинацию (сейчас CTRL+F12) или прописать отдельную горячую клавишу через стандартную секцию [Shortcuts].

Добавлено спустя 10 минут:

Update для кнопки, проверяющей новые файлы на wincmd.ru. В основном это исправление ошибок. Костяк функционала остается прежним. Полный архив с описанием и файлами.

Hidden text