Batya
|
 Posted: Tue Mar 03, 2009 13:15 Post subject: |
 |
|
ALekseyka
Вот переделанный вариант скрипта:
| Code: | '=====================================================================
' Перемещение выделенных файлов в соответствующие им папки на
' противоположной панели TC
' Папка соответствует файлу, если ее имя является началом имени файла
' Параметры вызова из TC:
' %L "%T"
'=====================================================================
Option Explicit
Dim Title, Mess, FSO, ListF, List, Target, Fold, File, Name, i
' Проверяем параметры
Title = "Внимание!"
If WScript.Arguments.Count < 2 Then
Mess = "Неправильно указаны параметры!"
MessQuit
End If
Set FSO = CreateObject("Scripting.FileSystemObject")
ListF = WScript.Arguments(0)
Target = WScript.Arguments(1)
If Not FSO.FileExists(ListF) Then
Mess = "Неправильно указан файл-список обрабатываемых файлов!"
MessQuit
End If
If Not FSO.FolderExists(Target) Then
Mess = "Неправильно указана целевая папка!"
MessQuit
End If
If Right(Target, 1) <> "\" Then Target = Target & "\"
List = Split(FSO.OpenTextFile(ListF).ReadAll, vbNewLine)
For Each File In List
Name = FSO.GetBaseName(File)
For i = Len(Name) To 1 Step -1
Fold = Target & Left(Name, i)
If FSO.FolderExists(Fold) Then
FSO.CopyFile File, Fold & "\", True
FSO.DeleteFile File
Exit For
End If
Next
Next
Quit
Sub MessQuit
MsgBox Mess, vbOKOnly + vbError, Title
Quit
End Sub
Sub Quit
Set FSO = Nothing
Wscript.Quit
End Sub |
_________________
Нет, я не сплю. Я просто медленно моргаю. |
|
Rules
Search
FAQ
Memberlist
Usergroups
Register
Profile
Log in to check your private messages
Log in
