Batya
|
 Posted: Mon Jun 27, 2011 09:30 Post subject: |
 |
|
KrechetovRS
Ещё один вариант vbs-скрипта:
| Code: | '=====================================================================
' Формирование для каждого файла из файла-списка m3u-файла,
' с содержимым вида:
' "nfs:<//ip-адрес:>|<диск:>/<Путь>/<к файлу>/<из файла-списка>/<имя файла>.<расширение>"
'
' Параметры:
' {файл-список}
'
' Примеры параметров при вызове из TC:
' %L
'=====================================================================
Option Explicit
Dim FSO, F, F1, FF, Str, D, N
Set FSO = CreateObject("Scripting.FileSystemObject")
With FSO.OpenTextFile(WScript.Arguments(0), 1)
Do While Not .AtEndOfStream
F = Trim(.ReadLine)
If F <> "" Then
If FSO.FileExists(F) Then
Str = FSO.GetFile(F).Path
Set D = FSO.GetDrive(FSO.GetDriveName(F))
N = InStr(Str, ":")
If (D.DriveType = 3) And (N > 0) Then Str = D.ShareName & Mid(Str, N+1)
If Left(Str, 2) = "\\" Then
N = InStr(3, Str, "\", 1)
Str = Left(Str, N-1) & ":" & Mid(Str, N)
End If
F1 = FSO.GetParentFolderName(F) & "\" & FSO.GetBaseName(F) & ".m3u"
Set FF = FSO.OpenTextFile(F1, 2, True)
FF.WriteLine "nfs:" & Replace(Str, "\", "/")
FF.Close
End If
End If
Loop
.Close
End With
Set D = Nothing
Set FF = Nothing
Set FSO = Nothing
Wscript.Quit()
|
_________________
Нет, я не сплю. Я просто медленно моргаю.
Last edited by Batya on Tue Jun 28, 2011 11:08; edited 2 times in total |
|
Rules
Search
FAQ
Memberlist
Usergroups
Register
Profile
Log in to check your private messages
Log in
