Flasher
|
 Posted: Fri Dec 25, 2015 19:18 Post subject: |
 |
|
А вообще не помешает пару скриптов непосредственно по теме:
| Code: | '======================= VBS =======================
' Замещение дат модификации выбранных файлов на даты
' модификации файлов с аналогичными базовыми именами
' Параметры: %WL <расширение одноимённых файлов>
'===================================================
With WScript.Arguments
C = .Count : If C = 0 Then WScript.Quit
List = .Item(0) : Ext = .Item(1)
End With
Set ShA = CreateObject("Shell.Application")
With CreateObject("Scripting.FileSystemObject")
Set File = .OpenTextFile(List,,,-1)
Do : F = File.ReadLine
Folder = .GetParentFolderName(F)
Name = .GetBaseName(F) & "." & Ext
If .FileExists(F) And .FileExists(Folder & "\" &_
Name) And LCase(Ext) <> LCase(.GetExtensionName(F)) Then
Set Folder = ShA.NameSpace(Folder)
Folder.ParseName(.GetFileName(F)).ModifyDate =_
Folder.ParseName(Name).ModifyDate
End If
Loop Until File.AtEndOfStream
End With |
| Code: | '=========================== VBS ===========================
' Замена дат создания и модификации выбранных файлов на даты
' создания и модификации файлов с аналогичным базовым именем
' Условие: требуется Script Helper ActiveX for TC by Volniy
' Параметры: %WL <расширение одноимённых файлов>
'===========================================================
With WScript.Arguments
C = .Count : If C = 0 Then WScript.Quit
List = .Item(0) : Ext = .Item(1)
End With
Set TCH = CreateObject("TCScript.Helper")
With CreateObject("Scripting.FileSystemObject")
Set File = .OpenTextFile(List,,,-1)
Do : F1 = File.ReadLine
If .FileExists(F1) Then
F2 = .GetParentFolderName(F1) & _
"\" & .GetBaseName(F1) & "." & Ext
If .FileExists(F2) And LCase(Ext) <> LCase(.GetExtensionName(F1)) Then
With .GetFile(F2)
TCH.SetFileDateAtr F1, .DateCreated, .DateLastModified
End With
End If
End If
Loop Until File.AtEndOfStream
End With |
_________________
Автору сборки TC Image (Andrey_A) настоятельно рекомендуется не распространять на иных ресурсах любую предоставленную мной где-либо техническую информацию по автоматизации и оптимизации в работе с ТС и системой. |
|
Rules
Search
FAQ
Memberlist
Usergroups
Register
Profile
Log in to check your private messages
Log in
