Single Post - Autorun :: Total Commander

Hidden text

Code:

Static hChildStdInWr = 0
Static hChildStdOutRd = 0
Static hChildStdInRd = 0
Static hChildStdOutWr = 0

Static hProcess = 0
Static hThread = 0

Func ET(FileName, FieldIndex, UnitIndex)
# Расположение файла Autorun.ini
# Location of Autorun.ini file
Local ini_TypeHints = COMMANDER_PATH & "\Ini\Autorun.ini"
# Читаем номер вида
# Reading type number
Local TypeHintsNum = IniRead(ini_TypeHints, "TypeHints", "CurrVal", 0)
# 0 - стандартный вид подсказки над файлами
# 1 - расширенный вид подсказки над файлами
If TypeHintsNum = 0 Then Return

If StrPos(FileGetAttr(FileName), "D") Then Return

Local sFile = "", j, files = 0, str
Local sPath = RequestCopyDataInfo("SP")
Local sName = RequestCopyDataInfo("SN")

Static aSel = List()
aSel.Count = 0
aSel.Text = GetSelectedItems(3, 0)
If aSel.Count = 0 Then aSel.Add(sName)

# Настройка атрибутов безопасности для наследования дескрипторов
Local Sec = Buffer(auX64 ? 24 : 12)
Sec.Zero()
Sec.SetNum(0, "UInt", Sec.size) # nLength
If auX64 Then
   Sec.SetNum(8, "Ptr", 0) # lpSecurityDescriptor
   Sec.SetNum(16, "Int", 1) # bInheritHandle
Else
   Sec.SetNum(4, "Ptr", 0)
   Sec.SetNum(8, "Int", 1)
EndIf

# Создаем Pipe для STDIN (Запись из Autorun -> Чтение в ExifTool)
If Not DllCall("CreatePipe", "Ptr*", @hChildStdInRd, "Ptr*", @hChildStdInWr, "Ptr", Sec.Ptr, "UInt", 0) Then
   MsgBox("Error CreatePipe STDIN")
   Return 0
EndIf

# Создаем Pipe для STDOUT (Запись из ExifTool -> Чтение в Autorun)
if Not DllCall("CreatePipe", "Ptr*", @hChildStdOutRd, "Ptr*", @hChildStdOutWr, "Ptr", Sec.Ptr, "UInt", 0) Then
   DllCall("CloseHandle", "Ptr", hChildStdInRd)
   DllCall("CloseHandle", "Ptr", hChildStdInWr)
   MsgBox("Error CreatePipe")
   Return 0
EndIf

# Запрещаем наследование нашей (записывающей/читающей) стороны каналов
DllCall("SetHandleInformation", "Ptr", hChildStdInWr, "UInt", 1, "UInt", 0)
DllCall("SetHandleInformation", "Ptr", hChildStdOutRd, "UInt", 1, "UInt", 0)

# Настройка STARTUPINFO
Local SI = Buffer(auPtrSize = 8 ? 104 : 68)
SI.Zero()
SI.SetNum(0, "UInt", SI.Size)
SI.SetNum(auX64 ? 60 : 44, "UInt", 0x00000101) # STARTF_USESTDHANDLES | STARTF_USESHOWWINDOW
SI.SetNum(auX64 ? 64 : 48, "UShort", 0) # SW_HIDE (скрывает окно консоли)
SI.SetNum(SI.Size - 3 * auPtrSize, "Ptr", hChildStdInRd)
SI.SetNum(SI.Size - 2 * auPtrSize, "Ptr", hChildStdOutWr)
SI.SetNum(SI.Size - auPtrSize, "Ptr", hChildStdOutWr) # Дублируем stdout в stderr

# Настройка PROCESS_INFORMATION
PI = Buffer(auPtrSize = 8 ? 24 : 16)
PI.Zero()

# Командная строка запуска
Local cmdLine = '"' & util_ET & '" -stay_open True -@ -'

# Флаг CREATE_NO_WINDOW (0x08000000) полностью блокирует создание консольного окна
If Not DllCall("CreateProcessW", "Ptr", 0, "WStr", cmdLine, _
   "Ptr", 0, "Ptr", 0, "Int", 1, "UInt", 0x08000000, _
   "Ptr", 0, "Ptr", 0, "Ptr", SI.Ptr, "Ptr", PI.Ptr) Then
   # Закрываем все открытые дескрипторы при ошибке
   DllCall("CloseHandle", "Ptr", hChildStdInRd)
   DllCall("CloseHandle", "Ptr", hChildStdInWr)
   DllCall("CloseHandle", "Ptr", hChildStdOutRd)
   DllCall("CloseHandle", "Ptr", hChildStdOutWr)
   MsgBox("Error CreateProcess")
   Return 0
EndIf

# Сохраняем нужные дескрипторы
hProcess = PI.GetNum(0, "Ptr")
hThread = PI.GetNum(auPtrSize, "Ptr")

# Закрываем дескрипторы, которые больше не нужны родительскому процессу
DllCall("CloseHandle", "Ptr", hChildStdInRd)
DllCall("CloseHandle", "Ptr", hChildStdOutWr)

WriteLine("-lang")
WriteLine("ru")
WriteLine("-m")
WriteLine("-q")
WriteLine("-q")
WriteLine(FileName)
WriteLine("-echo3")
WriteLine("{ready}")
WriteLine("-execute")
#MsgBox(hProcess & " " & hChildStdInWr & " " & hChildStdOutRd & " " & hChildStdInRd & " " & hChildStdOutWr )

Local output = "", chunk = ""

# Буфер для побайтового/посимвольного чтения из пайпа
Static readBuf = Buffer(1024*2)
readBuf.Zero()
While 1
   Local bytesRead = 0
   If Not DllCall("ReadFile", _
      "Ptr", hChildStdOutRd, _
      "Ptr", readBuf.Ptr, "UInt", readBuf.Size, "UInt*", @bytesRead, "Ptr", 0) Then
      Break
   EndIf

   If bytesRead <= 0 Then Break

   chunk = readBuf.GetStr(0, bytesRead, "ANSI")
   output &= chunk
   If StrPos(chunk, "{ready}") Then
      Break
   EndIf
Wend

# Очищаем результат от маркеров
output = StrReplace(output, "{ready}", "")

If hChildStdInWr Then
   WriteLine("-stay_open")
   WriteLine("False")
   DllCall("CloseHandle", "Ptr", hChildStdInWr)
   hChildStdInWr = 0
EndIf
If hChildStdOutRd Then
   DllCall("CloseHandle", "Ptr", hChildStdOutRd)
   hChildStdOutRd = 0
EndIf
if hProcess Then
   DllCall("CloseHandle", "Ptr", hProcess)
   hProcess = 0
EndIf
If hThread Then
   DllCall("CloseHandle", "Ptr", hThread)
   hThread = 0
EndIf
Return TrimSpaces1(StrPart(output, auLF, FieldIndex))
EndFunc

Func WriteLine(text)
rawString = text & auCRLF
# ExifTool ожидает UTF-8 или системную кодировку (зависит от настроек, UTF-8 наиболее универсален)
bufLen = StrLen(rawString) * 2
buf = Buffer(bufLen)
buf.Zero()
bufWr = buf.SetStr(rawString, 0, bufLen, "ANSI")
# Запись через WinAPI WriteFile
Local bytesWritten = 0
DllCall("WriteFile", "Ptr", hChildStdInWr, "Ptr", buf.ptr, "UInt", bufWr, "UInt*", @bytesWritten, "Ptr", 0)

Free(buf)
EndFunc

Func TrimSpaces1(String)
Local a, b
If Not StrPos(String, ":") Then Return String

a = StrPart(String, ": ", 1)
b = StrPart(String, ": ", 2)

Return StrTrim(FixCPET(a)) & ": " & StrTrim(FixCPET(b))
EndFunc

Func FixCPET(String)
Static a = List(), u = List()
Local ansi = String, utf8, wrong = Chr(0xFFFD)
Local nSize = StrLen(ansi)
Local buf = Buffer(nSize)
buf.Zero()
buf.SetStr(ansi, 0, nSize, "ANSI")
utf8 = buf.GetStr(0, nSize, "CP:65001")
Free(buf)
a.Count = 0
u.Count = 0
a.Text = ansi
u.Text = utf8
For i = 0 to u.Count - 1
   If StrPos(u[i], wrong) Then u[i] = a[i]
Next
Return u.text
EndFunc