Rodny
|
 Posted: Tue Apr 17, 2012 15:14 Post subject: |
 |
|
sergiokapone
Не совсем понятно, входной файл и "file.tif" в конце второй строки - одно и то же? И 10 раз повторяются эти две строки для одного файла? Если так, то что-то типа (не проверял!):
CPCTool.vbs :
| Code: | '==============================================================================
' Обработка выделенных файлов в CPCTool
' http://forum.wincmd.ru/viewtopic.php?p=91541#91541
'
' Параметры для кнопки (второй и третий параметры необязательны,
' их можно жёстко прописать в скрипте):
' %L [количество_повторений] "[путь к CPCTool]"
'
' Rodny (с)
'==============================================================================
Option Explicit
'====== Изменяемые параметры ==================================
' Количество повторений
Const DefaultCounter = 10
' Путь к CPCTool
Const DefaultPath = "D:\_install\Graphics\CPC Tool\CPC Tool 5.3\CPCTool-530-Win32-X86.exe"
'==============================================================
Dim FSO, ListFile, F, InputFile, OutputFile, CPCToolPath, Counter, i
Set FSO = CreateObject("Scripting.FileSystemObject")
With WScript
ListFile = .Arguments(0)
If .Arguments.Count > 1 Then
Counter = .Arguments(1)
Else
Counter = DefaultCounter
End If
If .Arguments.Count > 2 Then
CPCToolPath = .Arguments(2)
Else
CPCToolPath = DefaultPath
End If
End With
For Each F In Split(FSO.OpenTextFile(ListFile).ReadAll, vbNewLine)
If (F <> "") And (Right(F, 1) <> "\") Then
InputFile = """" & F & """"
OutputFile = FSO.GetParentFolderName(F) & "\" & FSO.GetBaseName(F) & ".cpc"
For i = 1 To Counter
With CreateObject("WScript.Shell")
.Run """" & CPCToolPath & """ " & InputFile & " -o """ & OutputFile & """", 0, True
.Run """" & CPCToolPath & """ """ & OutputFile & """ -o " & InputFile, 0, True
End With
Next
FSO.DeleteFile(OutputFile)
End If
Next
Set FSO = Nothing
Wscript.Quit |
Кнопка
| Code: | TOTALCMD#BAR#DATA
%COMMANDER_PATH%\Utils\Scripts\CPCTool.0.2.vbs
%L 10
C:\Windows\System32\WScript.exe,2
CPCTool.0.2
-1
|
Last edited by Rodny on Tue Apr 17, 2012 22:00; edited 5 times in total |
|
Rules
Search
FAQ
Memberlist
Usergroups
Register
Profile
Log in to check your private messages
Log in
